callback-query update doesen't show up in client

[EdvardPotapenko]

Basically, when I try to handle update of callback-query it appears as I've never pressed an inline button.
I've created log for every message type that bot handles - there is only "message" update type coming in.
I use esp8266 (Lolin new NodeMCU v3) with VS Code and platformio (platform = espressif8266, board = esp12e)
Here is my code:

#include <Arduino.h>
#include <ESP8266WiFi.h>
#include <WiFiClientSecure.h>
#include <UniversalTelegramBot.h> // Universal Telegram Bot Library written by Brian Lough: https://github.com/witnessmenow/Universal-Arduino-Telegram-Bot
#include <ArduinoJson.h>

// Wifi network station credentials
#define WIFI_SSID "***"
#define WIFI_PASSWORD "***"
// Telegram BOT Token (Get from Botfather)
#define BOT_TOKEN "***"

// Use @myidbot to find out the chat ID of an individual or a group
// Also note that you need to click "start" on a bot before it can
// message you
#define CHAT_ID "***"

X509List cert(TELEGRAM_CERTIFICATE_ROOT);

WiFiClientSecure secured_client;
UniversalTelegramBot bot(BOT_TOKEN, secured_client);

// Checks for new messages every 1 second.
int botRequestDelay = 1000;
unsigned long lastTimeBotRan;

void handleNewMessages(int numNewMessages)
{

    for (int i = 0; i < numNewMessages; i++)
    {
        Serial.println(bot.messages[i].type);
        // Inline buttons with callbacks when pressed will raise a callback_query message
        if (bot.messages[i].type == "callback_query")
        {
            Serial.print("Call back button pressed by: ");
            Serial.println(bot.messages[i].from_id);
            Serial.print("Data on the button: ");
            Serial.println(bot.messages[i].text);
            bot.sendMessage(bot.messages[i].from_id, bot.messages[i].text, "");
        }
        else
        {
            String chat_id = bot.messages[i].chat_id;
            String text = bot.messages[i].text;

            if (chat_id != CHAT_ID)
            {
                bot.sendMessage(chat_id, "Unauthorized user", "");
                continue;
            }

            String from_name = bot.messages[i].from_name;
            if (from_name == "")
                from_name = "Guest";

            if (text == "/options")
            {
                String keyboardJson = "[[{ \"text\" : \"Go to Google\", \"url\" : \"https://www.google.com\" }],[{ \"text\" : \"Send\", \"callback_data\" : \"DATA\" }]]";
                bot.sendMessageWithInlineKeyboard(chat_id, "Choose from one of the following options", "", keyboardJson);
            }

            if (text == "/start")
            {
                String welcome = "Welcome to Universal Arduino Telegram Bot library, " + from_name + ".\n";
                welcome += "This is Inline Keyboard Markup example.\n\n";
                welcome += "/options : returns the inline keyboard\n";

                bot.sendMessage(chat_id, welcome, "Markdown");
            }
        }
    }
}

void setup()
{
    Serial.begin(9600);

    configTime(0, 0, "pool.ntp.org"); // get UTC time via NTP
    secured_client.setTrustAnchors(&cert); // Add root certificate for api.telegram.org

    // Set WiFi to station mode and disconnect from an AP if it was Previously connected
    WiFi.mode(WIFI_STA);
    WiFi.disconnect();
    delay(100);

    // attempt to connect to Wifi network:
    Serial.print("Connecting to Wifi SSID ");
    Serial.print(WIFI_SSID);
    Serial.println(" ");
    WiFi.begin(WIFI_SSID, WIFI_PASSWORD);
    secured_client.setTrustAnchors(&cert); // Add root certificate for api.telegram.org
    while (WiFi.status() != WL_CONNECTED)
    {
        Serial.print(".");
        delay(500);
    }
    Serial.println();

    Serial.print("WiFi connected. IP address: ");
    Serial.println(WiFi.localIP());
}

void loop()
{
    if (millis() > lastTimeBotRan + botRequestDelay)  {
    int numNewMessages = bot.getUpdates(bot.last_message_received + 1);

    while(numNewMessages) {
      Serial.println("got response");
      handleNewMessages(numNewMessages);
      numNewMessages = bot.getUpdates(bot.last_message_received + 1);
    }
    lastTimeBotRan = millis();
  }
}

Answering simple messages and creating the inline-keyboard works completely fine, but inline-button can not be handled properly for some reason.

Anyway, you are doing great work - much thanks.

[EdvardPotapenko]

This was problem with my bot account, I was trying to reuse existing one. When I created new one everything started working.