Grammar-Kit [stable] [dev]

An IntelliJ IDEA plugin for language plugin developers.

Adds BNF Grammars and JFlex files editing support including parser/PSI code generator.

Open-source plugins built with Grammar-Kit:

Quick links: Changelog, Tutorial, How-to, Standalone usage.

General usage instructions

Create grammar *.bnf file, see Grammar.bnf in the plugin code.
Tune the grammar using Live Preview + Structure view (ctrl-alt-P / meta-alt-P)
Generate parser/ElementTypes/PSI classes (ctrl-shift-G / meta-shift-G)
Generate lexer *.flex file and then run JFlex generator (both via context menu)
Implement ParserDefinition and add the corresponding registrations to the plugin.xml
Mix-in resolve and other non-trivial functionality to PSI

Tooling support

Refactoring: extract rule (Ctrl-Alt-R/Meta-Alt-R)
Refactoring: introduce token (Ctrl-Alt-C/Meta-Alt-C)
Editing: flip choice branches intention (via Alt-Enter)
Editing: Unwrap/remove expression (Ctrl-Shift-Del/Meta-Shift-Del)
Navigation: quick grammar and flex file structure popup (Ctrl-F12/Meta-F12)
Navigation: go to related file (parser and PSI) (Ctrl-Alt-Home/Meta-Alt-Home)
Navigation: navigate to matched expressions (Ctrl-B/Meta-B inside attribute pattern)
Highlighting: customizable colors (via Settings/Colors and Fonts)
Highlighting: pinned expression markers (tooltip shows pin value in charge)
Highlighting: a number of inspections, the list is available in Settings/Inspections
Documentation: rule documentation popup shows FIRST/FOLLOWS/PSI content (Ctrl-Q/Meta-J)
Documentation: attribute documentation popup (Ctrl-Q/Meta-J)
Live preview: open language live preview editor (Ctrl-Alt-P/Meta-Alt-P)
Live preview: start/stop grammar evaluator highlighting (Ctrl-Alt-F7/Meta-Alt-F7 in preview editor)
Generator: generate parser/PSI code (Ctrl-Shift-G/Meta-Shift-G)
Generator: generate custom parserUtilClass class
Generator: generate *.flex - JFlex lexer definition
Generator: run JFlex generator on a *.flex file
Diagram: PSI tree diagram (UML plugin required)

Quick documentation:

See Parsing Expression Grammar for basic syntax. Use ::= for ← symbol. You can also use [ .. ] for optional sequences and { | | } for choices as these variants are popular in real-world grammars. Grammar-Kit source code is the main example of Grammar-Kit application. The grammar for BNF parser and PSI generation can be found here.

Here's how it may look like:

root_rule ::= rule_A rule_B rule_C rule_D                // a sequence
rule_A ::= token | 'or_text' | "another_one"             // a choice
rule_B ::= [ optional_token ] and_another_one?           // optional parts
rule_C ::= &required !forbidden                          // predicates
rule_D ::= { can_use_braces + (and_parens) * }           // grouping and repetition

// Grammar-Kit extensions:

private left rule_with_modifier ::= '+'                  // rule modifiers
left rule_with_attributes ::= '?' {elementType=rule_D}   // left rule and attributes

private meta list_macro ::= <<p>> (',' <<p>>) *          // meta rule
private list_usage ::= <<list_macro rule_D>>             // external expression

Basic syntax is extended with rule and global attributes that control code generation. Attributes are specified by the list of name=value pairs enclosed in { .. }. Rule attributes are placed right after the rule definition. Global attributes are placed on top or separated from a rule definition with a semicolon. Rule name or generated method name pattern can specify expression an attribute applies to:

{
  pin(".*_list(?:_\d.*)?")=1
}

This way you can keep grammar clean.

Rule modifiers:

private: PSI node will not be generated for this rule. Rules are public by default.
external: not generated. Used for generated and handwritten code integration.
left: left-associativity support. PSI node for this rule will enclose the one to the left.
inner: left-injection. PSI node for this rule will be injected into the one to the left.
meta: meta grammar support. Meta rules work in conjunction with external expressions.
fake: no parser code will be generated. For PSI hierarchy generation only.

Modifiers can be combined, inner should only be used together with left, private left is equivalent to private left inner.

Meta rules & external expressions:

External expression << ... >> is simply an inline variant of external rule. It can also be used to specify meta rule along with arguments.

For example:

meta comma_separated_list ::= <<param>> ( ',' <<param>> ) *
option_list ::= <<comma_separated_list (OPTION1 | OPTION2 | OPTION3)>>

External rule expression syntax is the same as a body of external expression:

 external manually_parsed_rule ::= methodName param1 param2 ...

Rule references in parameter list are implemented as GeneratedParserUtilBase.Parser instances.

Tokens:

Tokens should appear in grammar file as is. All conflicts can be resolved by quotation. If there is an attribute with the same value as single-quoted or double-quoted token then the corresponding IElementType constant will be generated and matched against otherwise the token will be matched by text.

Text-matched tokens can span more than one real token returned by lexer.

External expressions and external rules interpret double- and single-quoted strings differently. Generally anything that appears in an external expression after rule or method name is treated as parameter and passed "as is" except single-quoted strings. They are unquoted first. This helps passing qualified enum constants, java expressions, etc.

Attributes for error recovery and reporting:

pin tunes the parser to handle incomplete matches. A rule matches if the prefix of the rule up to the pinned token matches. Pinning an opening brace allows the parser to match the closing brace even if the tokens between them does not match the rule. Pin takes a position indicated by either a number (pin=2) or a pattern string (pin="rule_B").
recoverWhile (value: predicate rule) matches any number of tokens after the rule matching completes with any result. This attribute helps parser recover when unmatched token sequence is encountered. See HOWTO section for more.
name (value: string) specifies a name for a rule to be used in error reports. For example, *name("_.expr")=expression changes expression error messages to "<expression> required" instead of a long list of tokens.

Generated parser structure:

For each rule and every its sub-expression in a grammar a static method is generated. Sub-expression methods are named rule_name_K_L_.. where the (K, L, .. ) number list describes the position of a sub-expression in an enclosing rule. Avoid naming your rules this way.

Generator can split parser code into several classes for better support of large grammars.

For simple cases parser will consists just of several generated classes.

The actual error recovery and reporting code as well as completion functionality for parser-based completion provider and basic token matching code resides in a parserUtilClass class. It may be altered by specifying some other class that extend or mimic the original GeneratedParserUtilBase. There's no need to keep a copy of GeneratedParserUtilBase in a project, it is included in IntelliJ Platform since version 12.1.

The manual parsing code, i.e. external rules must be implemented the same way as generated, by a static method in the parserUtilClass class or any other class that will be imported via parserImports attribute like this:

{
  parserImports=["static org.sample.ManualParsing.*"]
}

Lexer and PSI:

IElementType constants generated by parser generator have to be recognized and returned by the lexer. JFlex-based lexer can be generated from grammar that defines all the required tokens ( Generate JFlex Lexer menu).

Run JFlex Generator menu in a *.flex file calls JFlex to generate lexer java code. Keywords are picked right from usages while tokens like string, identifier and comment can be defined like this (from TUTORIAL):

{
  tokens=[
    ...
    comment='regexp://.*'
    number='regexp:\d+(\.\d*)?'
    id='regexp:\p{Alpha}\w*'
    string="regexp:('([^'\\]|\\.)*'|\"([^\"\\]|\\.)*\")"
    ...
  ]
  ...
}

While Live Preview mode supports full Java RegExp syntax and JFlex supports only a subset (see JFlex documentation) Grammar-Kit tries to perform some obvious conversions.

Lexer can be provided separately or one can use the generated *.flex file as a base.

Parser generator generates token types constants and PSI by default. This can be switched off via generateTokens and generatePSI global boolean attributes respectively.

elementType rule attribute allows mixing the generated code and some existing hand-made PSI.

Standalone usage

Standalone generator

This way of running the parser generator has certain limitations in regards to PSI generation:

Method mixins require two-pass generation
Generic signatures may not be exact

Grammar-Kit depends on IntelliJ Platform classes. Required jars are specified in grammar-kit.jar!/META-INF/MANIFEST.MF. When running via java -jar one can either (1) provide original IntelliJ Platform jars in lib subfolder next to the grammar-kit.jar or (2) the experimental light-psi-all.jar right next to the grammar-kit.jar (only the required platform classes in one file built by LightPsi-All: Package run configuration).

<dir>
├─ lib/<IntelliJ jars> (1)
├─ light-psi-all.jar   (2)
└─ grammar-kit.jar

// java -jar
java -jar grammar-kit.jar <output-dir> <grammars-and-dirs>

// java -cp
java -cp grammar-kit.jar;<all-the-needed-jars> org.intellij.grammar.Main <output-dir> <grammars-and-dirs>

Gradle plugin is also available.

Standalone parser

The following command demonstrates the sample expression parser in action:

java -jar expression-console-sample.jar

davestimpert/Grammar-Kit